iris
00cc9309cb
de6e324bdseparate emu thread10d3daf86Roms List improvements95d202f37Let's make the rom list process on a separate thread so the emulator doesnt take ages to load.fc306967fWow the ROM Header was just completely busted. Game list view works nowbad1691eefuck this shit2b59e5f46game list in progressd26417b83remappable inputs in progressac4af8106inpute72abc240update readme430139dc9Qt6 frontend3080d4d45Fix this small bug too08cd13b85Cop0 unused functions do not actually pose a threat (as per manual). They don't do anything, so shall we.61bb4fb44make idle loop detection a little more specific with where the load goesb037de4c3SAZDFsdff12e81e73eneed to figure out why n64-systemtest loops indefinitely at some address that appears to be valid (i think it's me not invalidating the cache properly)204f0e13bidle skipping seems to work!cb8bb634asdkfjlasdf58e5c89c1Fix compilation issue on my machine (no idea)24fb2898eattempting more serious idle skipping214719577Place rsp.Step inside cached interpreter. Gains about 3 more fpsbb97dcc23mmmmm920b77d38wjkhasdfjhkasdf430ccdab4it's a start...4f42a673aCached interpreter plays Mario 64. Start looking into RSP as wellc9a030787idle skipping works!5fbda03cenew idea366637abaIdle skipping... maybe?609fa2fb0Cache instructions implemented but broken lmao. Commented out for nowe140a6d12- Stop using inheritance for CPU, instead use composition. - Introduce KAIZEN_JIT_ENABLED optional define instead of relying on __aarch64__ and the like. - More cache work68e613057prep cache impl811b4d809fix clang formatfda755f7didkd5024ebbfsmall MI refactor in preparation of (eventually) implementing the RDRAM interface properly694b45341Merge commit '206dcdedf195fb320913584180edb12c7731e396' as 'external/SDL'206dcdedfSquashed 'external/SDL/' content from commit 4d17b99d0a4d16e1cb4need to update sdl848b19920Fix compilation errordb61b5299Merge commit 'e94a94559f28e49678fbcf72199a5258137b0fe9' as 'external/imgui'e94a94559Squashed 'external/imgui/' content from commit 02e9b8cac52edb3757need to update imguic1a705e86Emulate weird JALR behaviour4b4c32f4bFix exception for "unusable COP1" in 4 instructions i missed accidentally (again)df5828142Bug putting 0s in the log everywheref8b580048Make isviewer a sink to file8241e9735Fix exception for "unusable COP1" in 4 instructions i missed accidentallyb29715f20small changesd9a620bc1make use of my new small utility library0d1aa938eAdd 'external/ircolib/' from commit 'ce3cd726c8df8388d554abf8bb55d55020eb4450'e64eb40b3Fuck git git-subtree-dir: external/ircolib git-subtree-split:de6e324bde
361 lines
19 KiB
CMake
361 lines
19 KiB
CMake
#
|
|
# CMake script for building the SDL examples
|
|
#
|
|
|
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/../cmake")
|
|
|
|
include(CheckIncludeFile)
|
|
include(CheckStructHasMember)
|
|
include(CMakePushCheckState)
|
|
include(sdlcompilers)
|
|
|
|
if(SDL_EXAMPLES_LINK_SHARED)
|
|
set(sdl_name_component SDL3-shared)
|
|
else()
|
|
set(sdl_name_component SDL3-static)
|
|
endif()
|
|
set(HAVE_EXAMPLES_LINK_SHARED "${SDL_EXAMPLES_LINK_SHARED}" PARENT_SCOPE)
|
|
|
|
set(SDL_EXAMPLE_EXECUTABLES)
|
|
|
|
if(CMAKE_RUNTIME_OUTPUT_DIRECTORY)
|
|
set(example_bin_dir "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
|
|
if(NOT IS_ABSOLUTE "${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
|
|
set(example_bin_dir "${CMAKE_CURRENT_BINARY_DIR}/${CMAKE_RUNTIME_OUTPUT_DIRECTORY}")
|
|
endif()
|
|
else()
|
|
set(example_bin_dir "${CMAKE_CURRENT_BINARY_DIR}")
|
|
endif()
|
|
if(NOT CMAKE_VERSION VERSION_LESS 3.20)
|
|
get_property(is_multi_config GLOBAL PROPERTY GENERATOR_IS_MULTI_CONFIG)
|
|
set(example_bin_dir "${example_bin_dir}$<$<BOOL:${is_multi_config}>:/$<CONFIG>>")
|
|
endif()
|
|
|
|
file(GLOB RESOURCE_FILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.png ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.wav ${CMAKE_CURRENT_SOURCE_DIR}/../test/*.hex)
|
|
|
|
set(RESOURCE_FILE_NAMES)
|
|
set(RESOURCE_FILES_BINDIR)
|
|
foreach(resource_file IN LISTS RESOURCE_FILES)
|
|
get_filename_component(res_file_name ${resource_file} NAME)
|
|
list(APPEND RESOURCE_FILE_NAMES "${res_file_name}")
|
|
set(resource_file_bindir "${example_bin_dir}/${res_file_name}")
|
|
add_custom_command(OUTPUT "${resource_file_bindir}"
|
|
COMMAND "${CMAKE_COMMAND}" -E copy "${resource_file}" "${resource_file_bindir}"
|
|
DEPENDS "${resource_file}"
|
|
)
|
|
list(APPEND RESOURCE_FILES_BINDIR "${resource_file_bindir}")
|
|
endforeach()
|
|
add_custom_target(copy-sdl-example-resources
|
|
DEPENDS "${RESOURCE_FILES_BINDIR}"
|
|
)
|
|
|
|
macro(add_sdl_example_executable TARGET)
|
|
cmake_parse_arguments(AST "BUILD_DEPENDENT" "" "SOURCES;DATAFILES" ${ARGN})
|
|
if(AST_UNPARSED_ARGUMENTS)
|
|
message(FATAL_ERROR "Unknown argument(s): ${AST_UNPARSED_ARGUMENTS}")
|
|
endif()
|
|
if(NOT AST_SOURCES)
|
|
message(FATAL_ERROR "add_sdl_example_executable needs at least one source")
|
|
endif()
|
|
if(ANDROID)
|
|
add_library(${TARGET} SHARED ${AST_SOURCES} ${AST_DATAFILES})
|
|
else()
|
|
add_executable(${TARGET} ${AST_SOURCES} ${AST_DATAFILES})
|
|
endif()
|
|
SDL_AddCommonCompilerFlags(${TARGET})
|
|
target_link_libraries(${TARGET} PRIVATE SDL3::${sdl_name_component})
|
|
|
|
list(APPEND SDL_EXAMPLE_EXECUTABLES ${TARGET})
|
|
if(AST_DATAFILES)
|
|
if(PSP OR PS2)
|
|
add_custom_command(TARGET ${TARGET} POST_BUILD
|
|
COMMAND ${CMAKE_COMMAND} ARGS -E make_directory $<TARGET_FILE_DIR:${TARGET}>/sdl-${TARGET}
|
|
COMMAND ${CMAKE_COMMAND} ARGS -E copy_if_different ${AST_DATAFILES} $<TARGET_FILE_DIR:${TARGET}>/sdl-${TARGET}
|
|
WORKING_DIRECTORY "${CMAKE_CURRENT_SOURCE_DIR}"
|
|
)
|
|
elseif(NOT APPLE AND NOT N3DS)
|
|
add_dependencies(${TARGET} copy-sdl-example-resources)
|
|
endif()
|
|
if(EMSCRIPTEN)
|
|
foreach(res IN LISTS AST_DATAFILES)
|
|
get_filename_component(res_name "${res}" NAME)
|
|
target_link_options(${TARGET} PRIVATE "SHELL:--embed-file ${res}@${res_name}")
|
|
endforeach()
|
|
endif()
|
|
set_property(TARGET ${TARGET} APPEND PROPERTY ADDITIONAL_CLEAN_FILES "$<TARGET_FILE_DIR:${TARGET}>/$<JOIN:${AST_DATAFILES},$<SEMICOLON>$<TARGET_FILE_DIR:${TARGET}>/>")
|
|
endif()
|
|
|
|
if(APPLE)
|
|
# Set Apple App ID / Bundle ID. This is needed to launch apps on some Apple
|
|
# platforms (iOS, for example).
|
|
set_target_properties(${TARGET} PROPERTIES
|
|
RESOURCES "${AST_DATAFILES}"
|
|
MACOSX_BUNDLE TRUE
|
|
MACOSX_BUNDLE_GUI_IDENTIFIER "org.libsdl.${TARGET}"
|
|
MACOSX_BUNDLE_BUNDLE_VERSION "${SDL3_VERSION}"
|
|
MACOSX_BUNDLE_SHORT_VERSION_STRING "${SDL3_VERSION}"
|
|
)
|
|
set_property(SOURCE ${AST_DATAFILES} PROPERTY MACOSX_PACKAGE_LOCATION "Resources")
|
|
elseif(WINDOWS)
|
|
# CET support was added in VS 16.7
|
|
if(MSVC_VERSION GREATER 1926 AND CMAKE_GENERATOR_PLATFORM MATCHES "Win32|x64")
|
|
set_property(TARGET ${TARGET} APPEND_STRING PROPERTY LINK_FLAGS " -CETCOMPAT")
|
|
endif()
|
|
elseif(EMSCRIPTEN)
|
|
set_property(TARGET ${TARGET} PROPERTY SUFFIX ".html")
|
|
target_link_options(${TARGET} PRIVATE -sALLOW_MEMORY_GROWTH=1)
|
|
elseif(N3DS)
|
|
set(ROMFS_DIR "${CMAKE_CURRENT_BINARY_DIR}/romfs/${TARGET}")
|
|
file(MAKE_DIRECTORY "${ROMFS_DIR}")
|
|
file(COPY ${AST_DATAFILES} DESTINATION "${ROMFS_DIR}")
|
|
ctr_generate_smdh("${TARGET}.smdh"
|
|
NAME "SDL-${TARGET}"
|
|
DESCRIPTION "SDL3 example application"
|
|
AUTHOR "SDL3 Contributors"
|
|
ICON "${CMAKE_CURRENT_SOURCE_DIR}/../test/n3ds/logo48x48.png"
|
|
)
|
|
ctr_create_3dsx(
|
|
${TARGET}
|
|
ROMFS "${ROMFS_DIR}"
|
|
SMDH "${TARGET}.smdh"
|
|
)
|
|
elseif(NGAGE)
|
|
string(MD5 TARGET_MD5 "${TARGET}")
|
|
string(SUBSTRING "${TARGET_MD5}" 0 8 TARGET_MD5_8)
|
|
target_link_options(${TARGET} PRIVATE "SHELL:-s UID3=0x${TARGET_MD5_8}")
|
|
endif()
|
|
endmacro()
|
|
|
|
add_sdl_example_executable(renderer-clear SOURCES renderer/01-clear/clear.c)
|
|
add_sdl_example_executable(renderer-primitives SOURCES renderer/02-primitives/primitives.c)
|
|
add_sdl_example_executable(renderer-lines SOURCES renderer/03-lines/lines.c)
|
|
add_sdl_example_executable(renderer-points SOURCES renderer/04-points/points.c)
|
|
add_sdl_example_executable(renderer-rectangles SOURCES renderer/05-rectangles/rectangles.c)
|
|
add_sdl_example_executable(renderer-textures SOURCES renderer/06-textures/textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-streaming-textures SOURCES renderer/07-streaming-textures/streaming-textures.c)
|
|
add_sdl_example_executable(renderer-rotating-textures SOURCES renderer/08-rotating-textures/rotating-textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-scaling-textures SOURCES renderer/09-scaling-textures/scaling-textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-geometry SOURCES renderer/10-geometry/geometry.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-color-mods SOURCES renderer/11-color-mods/color-mods.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-viewport SOURCES renderer/14-viewport/viewport.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-cliprect SOURCES renderer/15-cliprect/cliprect.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-read-pixels SOURCES renderer/17-read-pixels/read-pixels.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(renderer-debug-text SOURCES renderer/18-debug-text/debug-text.c)
|
|
add_sdl_example_executable(renderer-affine-textures SOURCES renderer/19-affine-textures/affine-textures.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png)
|
|
add_sdl_example_executable(audio-simple-playback SOURCES audio/01-simple-playback/simple-playback.c)
|
|
add_sdl_example_executable(audio-simple-playback-callback SOURCES audio/02-simple-playback-callback/simple-playback-callback.c)
|
|
add_sdl_example_executable(audio-load-wav SOURCES audio/03-load-wav/load-wav.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.wav)
|
|
add_sdl_example_executable(audio-multiple-streams SOURCES audio/04-multiple-streams/multiple-streams.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.wav ${CMAKE_CURRENT_SOURCE_DIR}/../test/sword.wav)
|
|
add_sdl_example_executable(audio-planar-data SOURCES audio/05-planar-data/planar-data.c)
|
|
add_sdl_example_executable(input-joystick-polling SOURCES input/01-joystick-polling/joystick-polling.c)
|
|
add_sdl_example_executable(input-joystick-events SOURCES input/02-joystick-events/joystick-events.c)
|
|
add_sdl_example_executable(input-gamepad-polling SOURCES input/03-gamepad-polling/gamepad-polling.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/gamepad_front.png)
|
|
add_sdl_example_executable(input-gamepad-events SOURCES input/04-gamepad-events/gamepad-events.c)
|
|
add_sdl_example_executable(camera-read-and-draw SOURCES camera/01-read-and-draw/read-and-draw.c)
|
|
add_sdl_example_executable(pen-drawing-lines SOURCES pen/01-drawing-lines/drawing-lines.c)
|
|
add_sdl_example_executable(asyncio-load-bitmaps SOURCES asyncio/01-load-bitmaps/load-bitmaps.c DATAFILES ${CMAKE_CURRENT_SOURCE_DIR}/../test/sample.png ${CMAKE_CURRENT_SOURCE_DIR}/../test/gamepad_front.png ${CMAKE_CURRENT_SOURCE_DIR}/../test/speaker.png ${CMAKE_CURRENT_SOURCE_DIR}/../test/icon2x.png)
|
|
add_sdl_example_executable(misc-power SOURCES misc/01-power/power.c)
|
|
add_sdl_example_executable(misc-clipboard SOURCES misc/02-clipboard/clipboard.c)
|
|
add_sdl_example_executable(misc-locale SOURCES misc/03-locale/locale.c)
|
|
add_sdl_example_executable(demo-snake SOURCES demo/01-snake/snake.c)
|
|
add_sdl_example_executable(demo-woodeneye-008 SOURCES demo/02-woodeneye-008/woodeneye-008.c)
|
|
add_sdl_example_executable(demo-infinite-monkeys SOURCES demo/03-infinite-monkeys/infinite-monkeys.c)
|
|
add_sdl_example_executable(demo-bytepusher SOURCES demo/04-bytepusher/bytepusher.c)
|
|
|
|
# When you add an example, remember to add the Visual Studio project as well:
|
|
# - Add a new example in examples/
|
|
# - Run python VisualC/examples/generate.py
|
|
# - Take note of the newly generated .vcxproj files
|
|
# - Modify the .vcxproj files if necessary (adding content such as PNG or WAV files)
|
|
# - Open VisualC/SDL.sln in Visual Studio or JetBrains Rider
|
|
# - Locate the appropriate folder in the Solution Explorer
|
|
# - Add the newly generated projects: Right click -> Add -> Existing project...
|
|
# - Test if they work
|
|
# - Save the SDL.sln solution
|
|
|
|
if(PSP)
|
|
# Build EBOOT files if building for PSP
|
|
foreach(APP ${SDL_EXAMPLE_EXECUTABLES})
|
|
create_pbp_file(
|
|
TARGET ${APP}
|
|
TITLE SDL-${APP}
|
|
ICON_PATH NULL
|
|
BACKGROUND_PATH NULL
|
|
PREVIEW_PATH NULL
|
|
OUTPUT_DIR $<TARGET_FILE_DIR:${APP}>/sdl-${APP}
|
|
)
|
|
endforeach()
|
|
endif()
|
|
|
|
if(RISCOS)
|
|
set(SDL_EXAMPLE_EXECUTABLES_AIF)
|
|
foreach(APP ${SDL_EXAMPLE_EXECUTABLES})
|
|
set_property(TARGET ${APP} APPEND_STRING PROPERTY LINK_FLAGS " -static")
|
|
add_custom_command(
|
|
OUTPUT ${APP},ff8
|
|
COMMAND elf2aif ${APP} ${APP},ff8
|
|
DEPENDS ${APP}
|
|
)
|
|
add_custom_target(${APP}-aif ALL DEPENDS ${APP},ff8)
|
|
list(APPEND SDL_EXAMPLE_EXECUTABLES_AIF ${CMAKE_CURRENT_BINARY_DIR}/${APP},ff8)
|
|
endforeach()
|
|
endif()
|
|
|
|
if(SDL_INSTALL_EXAMPLES)
|
|
if(RISCOS)
|
|
install(
|
|
FILES ${SDL_EXAMPLE_EXECUTABLES_AIF}
|
|
DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
|
|
)
|
|
else()
|
|
install(
|
|
TARGETS ${SDL_EXAMPLE_EXECUTABLES}
|
|
DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
|
|
)
|
|
endif()
|
|
if(MSVC)
|
|
foreach(example IN LISTS SDL_EXAMPLE_EXECUTABLES)
|
|
SDL_install_pdb(${example} "${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3")
|
|
endforeach()
|
|
endif()
|
|
install(
|
|
FILES ${RESOURCE_FILES}
|
|
DESTINATION ${CMAKE_INSTALL_LIBEXECDIR}/installed-examples/SDL3
|
|
)
|
|
endif()
|
|
|
|
if(ANDROID AND TARGET SDL3::Jar)
|
|
list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_LIST_DIR}/../cmake/android")
|
|
find_package(SdlAndroid MODULE)
|
|
if(SdlAndroid_FOUND)
|
|
set(apks "")
|
|
set(packages "")
|
|
|
|
include(SdlAndroidFunctions)
|
|
sdl_create_android_debug_keystore(SDL_example-debug-keystore)
|
|
sdl_android_compile_resources(SDL_example-resources RESFOLDER ${CMAKE_CURRENT_SOURCE_DIR}/../test/android/res)
|
|
add_custom_target(sdl-example-apks)
|
|
foreach(EXAMPLE ${SDL_EXAMPLE_EXECUTABLES})
|
|
set(ANDROID_MANIFEST_APP_NAME "${EXAMPLE}")
|
|
set(ANDROID_MANIFEST_LABEL "${EXAMPLE}")
|
|
set(ANDROID_MANIFEST_LIB_NAME "$<TARGET_FILE_BASE_NAME:${EXAMPLE}>")
|
|
set(ANDROID_MANIFEST_PACKAGE "org.libsdl.sdl.example.${EXAMPLE}")
|
|
set(generated_manifest_path "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-src/AndroidManifest.xml")
|
|
string(REPLACE "." "/" JAVA_PACKAGE_DIR "${ANDROID_MANIFEST_PACKAGE}")
|
|
set(GENERATED_SRC_FOLDER "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-src")
|
|
set(GENERATED_RES_FOLDER "${GENERATED_SRC_FOLDER}/res")
|
|
set(JAVA_PACKAGE_DIR "${GENERATED_SRC_FOLDER}/${JAVA_PACKAGE_DIR}")
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/SDLEntryTestActivity.java.cmake "${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java" @ONLY)
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/SDLTestActivity.java.cmake "${JAVA_PACKAGE_DIR}/SDLTestActivity.java" @ONLY)
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/res/values/strings.xml.cmake android/res/values/strings-${EXAMPLE}.xml @ONLY)
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/res/xml/shortcuts.xml.cmake "${GENERATED_RES_FOLDER}/xml/shortcuts.xml" @ONLY)
|
|
configure_file(${CMAKE_CURRENT_SOURCE_DIR}/../test/android/cmake/AndroidManifest.xml.cmake "${generated_manifest_path}" @ONLY)
|
|
file(GENERATE
|
|
OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-$<CONFIG>/res/values/strings.xml"
|
|
INPUT "${CMAKE_CURRENT_BINARY_DIR}/android/res/values/strings-${EXAMPLE}.xml"
|
|
)
|
|
|
|
sdl_android_compile_resources(${EXAMPLE}-resources
|
|
RESOURCES
|
|
"${CMAKE_CURRENT_BINARY_DIR}/android/${EXAMPLE}-$<CONFIG>/res/values/strings.xml"
|
|
"${GENERATED_RES_FOLDER}/xml/shortcuts.xml"
|
|
)
|
|
|
|
sdl_android_link_resources(${EXAMPLE}-apk-linked
|
|
MANIFEST "${generated_manifest_path}"
|
|
PACKAGE ${ANDROID_MANIFEST_PACKAGE}
|
|
RES_TARGETS SDL_example-resources ${EXAMPLE}-resources
|
|
TARGET_SDK_VERSION 31
|
|
)
|
|
|
|
set(CMAKE_JAVA_COMPILE_FLAGS "-encoding;utf-8")
|
|
set(classes_path "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${EXAMPLE}-java.dir/classes")
|
|
# Some CMake versions have a slow `cmake -E make_directory` implementation
|
|
if(NOT IS_DIRECTORY "${classes_path}")
|
|
execute_process(COMMAND ${CMAKE_COMMAND} -E make_directory "${classes_path}")
|
|
endif()
|
|
set(OUT_JAR "${CMAKE_CURRENT_BINARY_DIR}/${EXAMPLE}.jar")
|
|
add_custom_command(
|
|
OUTPUT "${OUT_JAR}"
|
|
COMMAND ${CMAKE_COMMAND} -E rm -rf "${classes_path}"
|
|
COMMAND ${CMAKE_COMMAND} -E make_directory "${classes_path}"
|
|
COMMAND ${Java_JAVAC_EXECUTABLE}
|
|
-source 1.8 -target 1.8
|
|
-bootclasspath "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>"
|
|
"${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java"
|
|
"${JAVA_PACKAGE_DIR}/SDLTestActivity.java"
|
|
$<TARGET_PROPERTY:${EXAMPLE}-apk-linked,JAVA_R>
|
|
-cp "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>:${SDL_ANDROID_PLATFORM_ANDROID_JAR}"
|
|
-d "${classes_path}"
|
|
COMMAND ${Java_JAR_EXECUTABLE} cf "${OUT_JAR}" -C "${classes_path}" .
|
|
DEPENDS $<TARGET_PROPERTY:${EXAMPLE}-apk-linked,OUTPUTS> "$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>" "${JAVA_PACKAGE_DIR}/SDLTestActivity.java" "${JAVA_PACKAGE_DIR}/SDLEntryTestActivity.java"
|
|
)
|
|
add_custom_target(${EXAMPLE}-jar DEPENDS "${OUT_JAR}")
|
|
set_property(TARGET ${EXAMPLE}-jar PROPERTY OUTPUT "${OUT_JAR}")
|
|
|
|
set(dexworkdir "${CMAKE_CURRENT_BINARY_DIR}/CMakeFiles/${EXAMPLE}-dex.dir")
|
|
# Some CMake versions have a slow `cmake -E make_directory` implementation
|
|
if(NOT IS_DIRECTORY "${dexworkdir}")
|
|
execute_process(COMMAND "${CMAKE_COMMAND}" -E make_directory "${dexworkdir}")
|
|
endif()
|
|
set(classes_dex_base_name "classes.dex")
|
|
set(classes_dex "${dexworkdir}/${classes_dex_base_name}")
|
|
add_custom_command(
|
|
OUTPUT "${classes_dex}"
|
|
COMMAND SdlAndroid::d8
|
|
$<TARGET_PROPERTY:${EXAMPLE}-jar,OUTPUT>
|
|
$<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>
|
|
--lib "${SDL_ANDROID_PLATFORM_ANDROID_JAR}"
|
|
--output "${dexworkdir}"
|
|
DEPENDS $<TARGET_PROPERTY:${EXAMPLE}-jar,OUTPUT> $<TARGET_PROPERTY:SDL3::Jar,JAR_FILE>
|
|
)
|
|
add_custom_target(${EXAMPLE}-dex DEPENDS "${classes_dex}")
|
|
set_property(TARGET ${EXAMPLE}-dex PROPERTY OUTPUT "${classes_dex}")
|
|
set_property(TARGET ${EXAMPLE}-dex PROPERTY OUTPUT_BASE_NAME "${classes_dex_base_name}")
|
|
|
|
sdl_add_to_apk_unaligned(${EXAMPLE}-unaligned-apk
|
|
APK_IN ${EXAMPLE}-apk-linked
|
|
OUTDIR "${CMAKE_CURRENT_BINARY_DIR}/intermediates"
|
|
ASSETS ${RESOURCE_FILES}
|
|
NATIVE_LIBS SDL3::SDL3-shared ${EXAMPLE}
|
|
DEX ${EXAMPLE}-dex
|
|
)
|
|
|
|
sdl_apk_align(${EXAMPLE}-aligned-apk ${EXAMPLE}-unaligned-apk
|
|
OUTDIR "${CMAKE_CURRENT_BINARY_DIR}/intermediates"
|
|
)
|
|
sdl_apk_sign(${EXAMPLE}-apk ${EXAMPLE}-aligned-apk
|
|
KEYSTORE SDL_example-debug-keystore
|
|
)
|
|
add_dependencies(sdl-example-apks ${EXAMPLE}-apk)
|
|
|
|
if(TARGET SdlAndroid::adb)
|
|
add_custom_target(install-${EXAMPLE}
|
|
COMMAND "${CMAKE_COMMAND}" -DACTION=install "-DAPKS=$<TARGET_PROPERTY:${EXAMPLE}-apk,OUTPUT>" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
|
|
DEPENDS "${EXAMPLE}-apk"
|
|
)
|
|
add_custom_target(start-${EXAMPLE}
|
|
COMMAND "${ADB_BIN}" shell am start-activity -S "${ANDROID_MANIFEST_PACKAGE}/.SDLTestActivity"
|
|
)
|
|
add_custom_target(build-install-start-${EXAMPLE}
|
|
COMMAND "${CMAKE_COMMAND}" -DACTION=build-install-run "-DEXECUTABLES=${EXAMPLE}" "-DBUILD_FOLDER=${CMAKE_BINARY_DIR}" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
|
|
)
|
|
endif()
|
|
|
|
list(APPEND packages "${ANDROID_MANIFEST_PACKAGE}")
|
|
list(APPEND install_targets install-${EXAMPLE})
|
|
endforeach()
|
|
|
|
if(TARGET SdlAndroid::adb)
|
|
add_custom_target(install-sdl-example-apks
|
|
DEPENDS ${install_targets}
|
|
VERBATIM
|
|
)
|
|
add_custom_target(uninstall-sdl-example-apks
|
|
COMMAND "${CMAKE_COMMAND}" "-DADB=$<TARGET_FILE:SdlAndroid::adb>" -DACTION=uninstall "-DPACKAGES=${packages}" -P "${SDL3_SOURCE_DIR}/cmake/android/SdlAndroidScript.cmake"
|
|
VERBATIM
|
|
)
|
|
endif()
|
|
endif()
|
|
endif()
|