iris
00cc9309cb
de6e324bdseparate emu thread10d3daf86Roms List improvements95d202f37Let's make the rom list process on a separate thread so the emulator doesnt take ages to load.fc306967fWow the ROM Header was just completely busted. Game list view works nowbad1691eefuck this shit2b59e5f46game list in progressd26417b83remappable inputs in progressac4af8106inpute72abc240update readme430139dc9Qt6 frontend3080d4d45Fix this small bug too08cd13b85Cop0 unused functions do not actually pose a threat (as per manual). They don't do anything, so shall we.61bb4fb44make idle loop detection a little more specific with where the load goesb037de4c3SAZDFsdff12e81e73eneed to figure out why n64-systemtest loops indefinitely at some address that appears to be valid (i think it's me not invalidating the cache properly)204f0e13bidle skipping seems to work!cb8bb634asdkfjlasdf58e5c89c1Fix compilation issue on my machine (no idea)24fb2898eattempting more serious idle skipping214719577Place rsp.Step inside cached interpreter. Gains about 3 more fpsbb97dcc23mmmmm920b77d38wjkhasdfjhkasdf430ccdab4it's a start...4f42a673aCached interpreter plays Mario 64. Start looking into RSP as wellc9a030787idle skipping works!5fbda03cenew idea366637abaIdle skipping... maybe?609fa2fb0Cache instructions implemented but broken lmao. Commented out for nowe140a6d12- Stop using inheritance for CPU, instead use composition. - Introduce KAIZEN_JIT_ENABLED optional define instead of relying on __aarch64__ and the like. - More cache work68e613057prep cache impl811b4d809fix clang formatfda755f7didkd5024ebbfsmall MI refactor in preparation of (eventually) implementing the RDRAM interface properly694b45341Merge commit '206dcdedf195fb320913584180edb12c7731e396' as 'external/SDL'206dcdedfSquashed 'external/SDL/' content from commit 4d17b99d0a4d16e1cb4need to update sdl848b19920Fix compilation errordb61b5299Merge commit 'e94a94559f28e49678fbcf72199a5258137b0fe9' as 'external/imgui'e94a94559Squashed 'external/imgui/' content from commit 02e9b8cac52edb3757need to update imguic1a705e86Emulate weird JALR behaviour4b4c32f4bFix exception for "unusable COP1" in 4 instructions i missed accidentally (again)df5828142Bug putting 0s in the log everywheref8b580048Make isviewer a sink to file8241e9735Fix exception for "unusable COP1" in 4 instructions i missed accidentallyb29715f20small changesd9a620bc1make use of my new small utility library0d1aa938eAdd 'external/ircolib/' from commit 'ce3cd726c8df8388d554abf8bb55d55020eb4450'e64eb40b3Fuck git git-subtree-dir: external/ircolib git-subtree-split:de6e324bde
109 lines
3.1 KiB
CMake
109 lines
3.1 KiB
CMake
# SDL cmake project-config input for CMakeLists.txt script
|
|
|
|
include(FeatureSummary)
|
|
set_package_properties(SDL3 PROPERTIES
|
|
URL "https://www.libsdl.org/"
|
|
DESCRIPTION "low level access to audio, keyboard, mouse, joystick, and graphics hardware"
|
|
)
|
|
|
|
@PACKAGE_INIT@
|
|
|
|
set(SDL3_FOUND TRUE)
|
|
set(_sdl3_framework @SDL_FRAMEWORK@)
|
|
|
|
# Find SDL3::Headers
|
|
if(NOT TARGET SDL3::Headers)
|
|
include("${CMAKE_CURRENT_LIST_DIR}/SDL3headersTargets.cmake")
|
|
if(NOT CMAKE_VERSION VERSION_LESS "3.25")
|
|
set_property(TARGET SDL3::Headers PROPERTY SYSTEM 0)
|
|
endif()
|
|
endif()
|
|
set(SDL3_Headers_FOUND TRUE)
|
|
|
|
# Find SDL3::SDL3-shared
|
|
if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/SDL3sharedTargets.cmake")
|
|
include("${CMAKE_CURRENT_LIST_DIR}/SDL3sharedTargets.cmake")
|
|
set(SDL3_SDL3-shared_FOUND TRUE)
|
|
endif()
|
|
|
|
macro(find_sdl3_static_dependencies)
|
|
@SDL_FIND_PKG_CONFIG_COMMANDS@
|
|
endmacro()
|
|
|
|
# Find SDL3::SDL3-static
|
|
if(_sdl3_framework)
|
|
set(SDL3_SDL3-static_FOUND TRUE)
|
|
find_sdl3_static_dependencies()
|
|
find_package(SDL3-static CONFIG QUIET)
|
|
if(SDL3_SDL3-static_FOUND AND SDL3-static_FOUND)
|
|
set(SDL3_SDL3-static_FOUND TRUE)
|
|
endif()
|
|
else()
|
|
if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/SDL3staticTargets.cmake")
|
|
set(SDL3_SDL3-static_FOUND TRUE)
|
|
find_sdl3_static_dependencies()
|
|
if(SDL3_SDL3-static_FOUND)
|
|
if(ANDROID OR HAIKU)
|
|
enable_language(CXX)
|
|
endif()
|
|
include("${CMAKE_CURRENT_LIST_DIR}/SDL3staticTargets.cmake")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(ANDROID AND EXISTS "${CMAKE_CURRENT_LIST_DIR}/SDL3jarTargets.cmake")
|
|
include("${CMAKE_CURRENT_LIST_DIR}/SDL3jarTargets.cmake")
|
|
set(SDL3_Jar_FOUND TRUE)
|
|
endif()
|
|
|
|
if(SDL3_SDL3-shared_FOUND OR SDL3_SDL3-static_FOUND)
|
|
set(SDL3_SDL3_FOUND TRUE)
|
|
endif()
|
|
|
|
# Find SDL3::SDL3_test
|
|
if(_sdl3_framework)
|
|
find_package(SDL3_test CONFIG QUIET)
|
|
if(SDL3_test_FOUND)
|
|
enable_language(OBJC)
|
|
set(SDL3_SDL3_test_FOUND TRUE)
|
|
endif()
|
|
else()
|
|
if(EXISTS "${CMAKE_CURRENT_LIST_DIR}/SDL3testTargets.cmake")
|
|
set(SDL3_SDL3_test_FOUND TRUE)
|
|
@SDL_TEST_FIND_PKG_CONFIG_COMMANDS@
|
|
if(SDL3_SDL3_test_FOUND)
|
|
include("${CMAKE_CURRENT_LIST_DIR}/SDL3testTargets.cmake")
|
|
endif()
|
|
endif()
|
|
endif()
|
|
|
|
if(NOT SDL3_COMPONENTS AND NOT TARGET SDL3::Headers AND NOT TARGET SDL3::SDL3-shared AND NOT TARGET SDL3::SDL3-static)
|
|
set(SDL3_FOUND FALSE)
|
|
endif()
|
|
check_required_components(SDL3)
|
|
|
|
function(_sdl_create_target_alias_compat NEW_TARGET TARGET)
|
|
if(CMAKE_VERSION VERSION_LESS "3.18")
|
|
# Aliasing local targets is not supported on CMake < 3.18, so make it global.
|
|
add_library(${NEW_TARGET} INTERFACE IMPORTED)
|
|
set_target_properties(${NEW_TARGET} PROPERTIES INTERFACE_LINK_LIBRARIES "${TARGET}")
|
|
else()
|
|
add_library(${NEW_TARGET} ALIAS ${TARGET})
|
|
endif()
|
|
endfunction()
|
|
|
|
# Make sure SDL3::SDL3 always exists
|
|
if(NOT TARGET SDL3::SDL3)
|
|
if(TARGET SDL3::SDL3-shared)
|
|
_sdl_create_target_alias_compat(SDL3::SDL3 SDL3::SDL3-shared)
|
|
elseif(TARGET SDL3::SDL3-static)
|
|
_sdl_create_target_alias_compat(SDL3::SDL3 SDL3::SDL3-static)
|
|
endif()
|
|
endif()
|
|
|
|
set(SDL3_LIBRARIES SDL3::SDL3)
|
|
set(SDL3_STATIC_LIBRARIES SDL3::SDL3-static)
|
|
set(SDL3_STATIC_PRIVATE_LIBS)
|
|
|
|
set(SDL3TEST_LIBRARY SDL3::SDL3_test)
|